Symulator ułatwiający dobieranie punktu pracy lampy

Teoria lamp elektronowych, techniki próżniowe, zagadnienia konstrukcyjne. Nic dodać, nic ująć. Wszystko o lampach.

Moderatorzy: gsmok, tszczesn, Romekd, Einherjer, OTLamp

Awatar użytkownika
Piotr
moderator
Posty: 8656
Rejestracja: pn, 30 czerwca 2003, 12:38
Lokalizacja: Kraków, Ślusarska 9
Kontakt:

Re: Symulator ułatwiający dobieranie punktu pracy lampy

Post autor: Piotr »

Dołączam się do podziękowań za udostępnienie symulatora, rzecz jest znakomita.

Gdyby była taka możliwość, to prosiłbym o uwzględnienie charakterystyk 6N7 (6N7S), jedynej jakiej obecnie mi brakuje.
Awatar użytkownika
Locutus
1875...2499 postów
1875...2499 postów
Posty: 2001
Rejestracja: sob, 4 sierpnia 2007, 23:09
Lokalizacja: LubLin

Re: Symulator ułatwiający dobieranie punktu pracy lampy

Post autor: Locutus »

W słowie 'operating' zdania "Parameters at operaing point" zabrakło litery 't'.

Ze swojej strony przylączam się do prośby o EL34 w trybie pentody oraz EBL21.
Czy są szanse na EF21 w trybie troidy ?
Katalog podaje, że polska EF21 (pentoda uniwersalna) to to samo co EF6.
jackie01
250...374 postów
250...374 postów
Posty: 294
Rejestracja: ndz, 16 stycznia 2011, 18:51

Re: Symulator ułatwiający dobieranie punktu pracy lampy

Post autor: jackie01 »

Mam pytanie do praktyków - czy wyznaczone przez symulator zniekształcenia harmoniczne w danym punkcie pracy dla zadanego Uin mają pokrycie w rzeczywistości?
Pytam ponieważ zadając dany punkt pracy do LTSpice'a (Ub, Ra, Rk) dla identycznego sygnału wejściowego Uin otrzymuję niestety inny prąd Ia a co za tym idzie Ua. Zniekształcenia również nie mają pokrycia - są znacznie wyższe. Dla wersji bez kondensatora w katodzie otrzymuję dwa razy większe zniekształcenia, z kondensatorem w katodzie już 4krotnie większe niż te ze strony symulatora online. Nie są to już kosmetyczne różnice. Nie sądzę, że to wina modelu lampy - dla innych mam podobne wyniki. Gdzieś na pewno popełniam błąd - być może w rozumowaniu. Dołożenie kondensatora zmniejsza lokalne sprzężenie zwrotne, zwiększa wzmocnienie lampy - czy dla takiej sytuacji należy szukać nowego punktu pracy i wtedy symulator online ze strony Triody nie zdaje egzaminu? Najlepiej byłoby sprawdzić układ w rzeczywistości i dokonać konfrontacji ale zapytać kolegów nie zaszkodzi a nuż coś mi doradzicie?
Symulator online Trioda
Symulator online Trioda
LTspice - bez kondensatora katodowego
LTspice - bez kondensatora katodowego
LTspice - z kondensatorem katodowym
LTspice - z kondensatorem katodowym
Awatar użytkownika
tszczesn
moderator
Posty: 10918
Rejestracja: wt, 12 sierpnia 2003, 09:14
Lokalizacja: Otwock
Kontakt:

Re: Symulator ułatwiający dobieranie punktu pracy lampy

Post autor: tszczesn »

Czy w LTSpice korzystasz z dokładnie tego samego modelu lampy co w programie w którym projektujesz punkt pracy? Bo jak nie, to nie masz jak przełożyć wyników z jednego miejsca na drugie.
jackie01
250...374 postów
250...374 postów
Posty: 294
Rejestracja: ndz, 16 stycznia 2011, 18:51

Re: Symulator ułatwiający dobieranie punktu pracy lampy

Post autor: jackie01 »

Zapewne modele różnią się od siebie ale próbowałem kilku różnych modeli 6N1P-EW w LTspice w tym jeden który stworzyłem naprędce sam. Wynik - zawsze odstępstwo - niestety zawsze w tą złą stronę - czyli dużo wyższe zniekształcenia. Można pokusić się o stwierdzenie, że przynajmniej jeden (jeśli nie oba) symulatory dają wyniki z kapelusza? Jedyna droga weryfikacji to przetestowanie kilku egzemplarzy lampy w realnym układzie i pomiar.
Awatar użytkownika
tszczesn
moderator
Posty: 10918
Rejestracja: wt, 12 sierpnia 2003, 09:14
Lokalizacja: Otwock
Kontakt:

Re: Symulator ułatwiający dobieranie punktu pracy lampy

Post autor: tszczesn »

Pomiar w naturze to zawsze ostateczna weryfikacja symulacji. A wyniki symulacji wprost zależą od użytych modeli elementów, więc porównywanie ze sobą rezultatów osiągniętych za pomocą różnych modeli nie ma sensu, można je tylko porównać z naturą i zobaczyć który bardziej odbiega od rzeczywistości.
Awatar użytkownika
gsmok
3125...6249 postów
3125...6249 postów
Posty: 3807
Rejestracja: wt, 8 kwietnia 2003, 08:33
Lokalizacja: Warszawa
Kontakt:

Re: Symulator ułatwiający dobieranie punktu pracy lampy

Post autor: gsmok »

Wygeneruj w LTSpice charakterystyki anodowe i porównaj je z symulatorem. Wzory, na podstawie których w symulatorze metodami graficznymi wyznaczane są zniekształcenia masz w opisie podanym w linku pod symulatorem.
Pozdrawiam
Grzegorz Makarewicz 'gsmok'
Awatar użytkownika
Locutus
1875...2499 postów
1875...2499 postów
Posty: 2001
Rejestracja: sob, 4 sierpnia 2007, 23:09
Lokalizacja: LubLin

Re: Symulator ułatwiający dobieranie punktu pracy lampy

Post autor: Locutus »

Einherjer
1875...2499 postów
1875...2499 postów
Posty: 2111
Rejestracja: pt, 22 stycznia 2010, 18:34
Lokalizacja: Wałbrzych

Re: Symulator ułatwiający dobieranie punktu pracy lampy

Post autor: Einherjer »

@Loctus Z tego co widzę, teraz sam możesz wyznaczyć parametry modelu bezpośrednio na stronie.
@gsmok Pewnie już czytałeś, ale jakby nie to zajrzyj koniecznie: http://dos4ever.com/uTracer3/Theory.pdf
CHOPIN66
1875...2499 postów
1875...2499 postów
Posty: 1875
Rejestracja: pn, 10 sierpnia 2009, 17:47
Lokalizacja: Gdańsk

Re: Symulator ułatwiający dobieranie punktu pracy lampy

Post autor: CHOPIN66 »

Przydała by się PCF82 .
Awatar użytkownika
gsmok
3125...6249 postów
3125...6249 postów
Posty: 3807
Rejestracja: wt, 8 kwietnia 2003, 08:33
Lokalizacja: Warszawa
Kontakt:

Re: Symulator ułatwiający dobieranie punktu pracy lampy

Post autor: gsmok »

Będę się starał, ale dopiero po nowym roku. Z góry przepraszam - to z powodu lenistwa :oops:
Pozdrawiam
Grzegorz Makarewicz 'gsmok'
Awatar użytkownika
gsmok
3125...6249 postów
3125...6249 postów
Posty: 3807
Rejestracja: wt, 8 kwietnia 2003, 08:33
Lokalizacja: Warszawa
Kontakt:

Re: Symulator ułatwiający dobieranie punktu pracy lampy

Post autor: gsmok »

Modele lamp elektronowych:

Plik 6bq5.inc

*-----------------------------------------------------------------------
* Filename: 6bq5.inc 23/01/2004 V4
* Simulator: PSpice
* Device type: Power pentode
* Device model: 6BQ5/EL84
*
* Author: Duncan Munro
* Date: 12/5/97
* Copyright: (C)1997-2004 Duncan Amplification
*
*
* V3 [12/10/97]: Screen current limited to prevent screen current
* draw at Vs = 0.
*
* V4 [23/01/04]: LIMIT{x,y,z} statements changed to LIMIT(x,y,z)
*
* The following parameters are not modelled:
*
* (1) Heater
* (2) Grid current is an approximation
*
* Please note that this model is provided "as is" and
* no warranty is provided in respect of its suitability
* for any application.
*
* This model is provided for educational and non-profit use.
*
* Queries via the forum at http://www.duncanamps.com/
*
* Pins A Anode
* S Screen
* G Grid
* K Cathode
*
*-----------------------------------------------------------------------

.SUBCKT 6BQ5 A S G K
*
* Calculate contribution to cathode current
*
Eat at 0 VALUE={0.636*ATAN(V(A,K)/15)}
Egs gs 0 VALUE={LIMIT(V(S,K)/19+V(G,K)+V(A,K)/1400,0,1E6)}
Egs2 gs2 0 VALUE={PWRS(V(gs),1.5)}
Ecath cc 0 VALUE={V(gs2)*V(at)}
*
* Calculate anode current
*
Ga A K VALUE={3.2E-3*V(cc)}
*
* Calculate screen current
*
Escrn sc 0 VALUE={V(gs2)*(1.1-V(at))}
Gs S K VALUE={2.0E-3*V(sc)*LIMIT(V(S,K),0,10)/10}
*
* Grid current (approximation - does not model low va/vs)
*
Gg G K VALUE={PWR(LIMIT(V(G,K)+1,0,1E6),1.5)*50E-6}
*
* Capacitances
*
Cg1 G K 10.8p
Cak A K 6.5p
Cg1a G A 0.5p

.ENDS
Pozdrawiam
Grzegorz Makarewicz 'gsmok'
Awatar użytkownika
gsmok
3125...6249 postów
3125...6249 postów
Posty: 3807
Rejestracja: wt, 8 kwietnia 2003, 08:33
Lokalizacja: Warszawa
Kontakt:

Re: Symulator ułatwiający dobieranie punktu pracy lampy

Post autor: gsmok »

Modele lamp cd.

Plik dmtriodep.inc

**********************************************************************
* Duncan Amplfication Generic Triode Model (PSpice Implementation)
* Copyright (C)1997-2004 Duncan Amplfication
* Unauthorised Commercial use prohibited
* Please refer to documentation at http://www.duncanamps.com
*
* $MODEL_VERSION$ 4.1
* $AUTOGENERATED$ 23/01/2004 20:24:26
**********************************************************************
* CURRENT MODEL SET AND VERSIONS:
*
* 2A3 [3.2, 09/08/2003 ]
* 3CX300 [3.1, 05/01/1998 ]
* SV6AS7 [3.0, 30/12/1997 ]
* 6BM8 / ECL82 [3.0, 31/12/1997 ]
* 6DJ8 / ECC88 [3.0, 15/08/1998 ]
* 6N1P [3.0, 25/01/1998 ]
* 6SN7GTB [3.1, 05/01/1998 ]
* 12AT7 / ECC81 [3.1, 05/01/1998 ]
* 12AU7 / ECC82 [3.2, 01/05/2002 ]
* 12AX7 / ECC83 [3.0, 30/12/1997 ]
* 76 [3.0, 12/02/1998 ]
* 300B [3.1, 06/01/1998 ]
* SV572-3 [3.0, 31/12/1997 ]
* SV572-10 [3.0, 20/06/1998 ]
* 5751 [3.0, 15/02/1998 ]
**********************************************************************
* CORE MODEL VERSION HISTORY:
*
* 1.0 23/09/1997 Initial model
* 1.1 19/11/1997 Model altered for 1 gig resistors between each node and ground
* 2.0 18/12/1997 Two new parameters, ERP and ERI added
* 3.0 30/12/1997 New parameter added, RAS
* 3.1 05/01/1998 ERI parameter removed
* 3.2 06/01/1998 Fix errors in Pspice model
* 3.3 13/01/1998 Fixed errors with CDO parameter
* 3.4 25/01/1998 Errors with heater versions using ERI fixed
* 4.1 23/01/2004 Corrections to Pspice syntax for LTSpice
**********************************************************************
.SUBCKT TRIODE A G K H1 H2
+PARAMS: RCO=1.6 RHO=10.5 HTV=6.3 HWU=10.5
+ LIP=1 LIF=3.7E-3 RAF=18E-3 RAS=1 CDO=0 RAP=4E-3
+ ERP=1.5
+ MU0=17.3 MUR=19E-3 EMC=9.6E-6 GCO=0 GCF=213E-6
+ CGA=3.9p CGK=2.4p CAK=0.7p

************************************************************************
*
* Heater model
*
* Can be operated from AC or DC power sources.
* NB: When operating from DC power sources, "Skip initial transient
* solution" must be checked, to make use of this model.
*
* PARAMETERS
*
* RCO Heater resistance cold (ohms)
* RHO Heater resistance hot (ohms)
* HTV Normal heater voltage (V)
* HWU Heater time to warm up to 90% of emission (seconds)
*
************************************************************************

Rcool H1 HA {RCO}
Rload HA HB 1M
Esens HD 0 VALUE {V(HA,HB)*1000}
Epwr HE 0 VALUE {V(H1,H2)*V(HD)/(PWR({HTV},2)/{RHO})}
RH1 HE HF 91k
CH1 HF 0 {HWU/1E6}
EH2 HG 0 VALUE {V(HF)}
RH2 HG HH 270k
CH2 HH 0 {HWU/1E6}
EH3 HJ 0 VALUE {LIMIT(V(HH)-0.75,0,1E6)*4}
RH3 HJ HK 91k
CH3 HK 0 {HWU/1E6}
Ghot HB H2 VALUE {(1/(V(HG)+0.001))/({RHO}-{RCO})*V(HB,H2)}

************************************************************************
*
* Anode/grid model
*
* Models reduction in mu at large negative grid voltages
* Models change in Ra with negative grid voltages
* Models limit in Ia with high +Vg and low Va
*
* PARAMETERS
*
* LIP Conduction limit exponent
* LIF Conduction limit factor
* CDO Conduction offset
* RAF Anode resistance factor for neg grid voltages
* RAP Anode resistance factor for positive grid voltages
* ERP Emission power
* MU0 Mu between grid and anode at Vg=0
* MUR Mu reduction factor for large negative grid voltages
* EMC Emission coefficient
* GCO Grid current offset in volts
* GCF Grid current scale factor
*
************************************************************************

Elim LI 0 VALUE {PWR(LIMIT(V(A,K),0,1E6),{LIP})*{LIF}}
Egg GG 0 VALUE {V(G,K)-{CDO}}
Erpf RP 0 VALUE {1-PWR(LIMIT(-V(GG)*{RAF},0,0.999),{RAS})+LIMIT(V(GG),0,1E6)*{RAP}}
Egr GR 0 VALUE {LIMIT(V(GG),0,1E6)+LIMIT((V(GG))*(1+V(GG)*{MUR}),0,-1E6)}
Eem EM 0 VALUE {LIMIT(V(A,K)+V(GR)*{MU0},0,1E6)}
Eep EP 0 VALUE {PWR(V(EM),ERP)*{EMC}*V(RP)}
Eel EL 0 VALUE {LIMIT(V(EP),0,V(LI))}
Eld LD 0 VALUE {LIMIT(V(EP)-V(LI),0,1E6)}
Ga A K VALUE {V(HK)*V(EL)}

************************************************************************
*
* Grid current model
*
* Models grid current, along with rise in grid current at low Va
*
************************************************************************
Egf GF 0 VALUE {PWR(LIMIT(V(G,K)-{GCO},0,1E6),1.5)*{GCF}}
Gg G K VALUE {(V(GF)+V(LD))*V(HK)}

*
* Capacitances and anti-float resistors
*
CM1 G K {CGK}
CM2 A G {CGA}
CM3 A K {CAK}
RF1 A 0 1000MEG
RF2 G 0 1000MEG
RF3 K 0 1000MEG

.ENDS

.SUBCKT TRIODENH A G K
+PARAMS: LIP=1 LIF=3.7E-3 RAF=18E-3 RAS=1 CDO=0 RAP=4E-3
+ ERP=1.5
+ MU0=17.3 MUR=19E-3 EMC=9.6E-6 GCO=0 GCF=213E-6
+ CGA=3.9p CGK=2.4p CAK=0.7p

************************************************************************
*
* Anode/grid model
*
* Models reduction in mu at large negative grid voltages
* Models change in Ra with negative grid voltages
* Models limit in Ia with high +Vg and low Va
*
* PARAMETERS
*
* LIP Conduction limit exponent
* LIF Conduction limit factor
* CDO Conduction offset
* RAF Anode resistance factor for neg grid voltages
* RAP Anode resistance factor for positive grid voltages
* ERP Emission power
* MU0 Mu between grid and anode at Vg=0
* MUR Mu reduction factor for large negative grid voltages
* EMC Emission coefficient
* GCO Grid current offset in volts
* GCF Grid current scale factor
*
************************************************************************

Elim LI 0 VALUE {PWR(LIMIT(V(A,K),0,1E6),{LIP})*{LIF}}
Egg GG 0 VALUE {V(G,K)-{CDO}}
Erpf RP 0 VALUE {1-PWR(LIMIT(-V(GG)*{RAF},0,0.999),{RAS})+LIMIT(V(GG),0,1E6)*{RAP}}
Egr GR 0 VALUE {LIMIT(V(GG),0,1E6)+LIMIT((V(GG))*(1+V(GG)*{MUR}),0,-1E6)}
Eem EM 0 VALUE {LIMIT(V(A,K)+V(GR)*{MU0},0,1E6)}
Eep EP 0 VALUE {PWR(V(EM),ERP)*{EMC}*V(RP)}
Eel EL 0 VALUE {LIMIT(V(EP),0,V(LI))}
Eld LD 0 VALUE {LIMIT(V(EP)-V(LI),0,1E6)}
Ga A K VALUE {V(EL)}

************************************************************************
*
* Grid current model
*
* Models grid current, along with rise in grid current at low Va
*
************************************************************************
Egf GF 0 VALUE {PWR(LIMIT(V(G,K)-{GCO},0,1E6),1.5)*{GCF}}
Gg G K VALUE {(V(GF)+V(LD))}

*
* Capacitances and anti-float resistors
*
CM1 G K {CGK}
CM2 A G {CGA}
CM3 A K {CAK}
RF1 A 0 1000MEG
RF2 G 0 1000MEG
RF3 K 0 1000MEG

.ENDS
**********************************************************************
* GENERIC: 2A3
* MODEL: NH2A3
* NOTES: No heater model (virtual cathode)
**********************************************************************
.SUBCKT NH2A3 A G K
XV1 A G K TRIODENH
+PARAMS: LIP= 1.5 LIF= 0.003 RAF= 1.92357959289845E-02 RAS= 5.31355720568454E-02 CDO= 0
+ RAP= 0.005 ERP= 1.55
+ MU0= 4.2 MUR= 0.001023047 EMC= 0.0000868
+ GCO=-0.2 GCF= 0.00001
+ CGA=1.65E-11 CGK=7.50E-12 CAK=5.50E-12
.ENDS

**********************************************************************
* GENERIC: 3CX300
* MODEL: NH3CX300
* NOTES: No heater model
**********************************************************************
.SUBCKT NH3CX300 A G K
XV1 A G K TRIODENH
+PARAMS: LIP= 1.5 LIF= 10 RAF= 0.00536 RAS= 1 CDO= 0
+ RAP= 0.005 ERP= 1.25
+ MU0= 8.321 MUR= 0.0012 EMC= 0.000533
+ GCO= 0 GCF= 0.0001
+ CGA=1.00E-11 CGK=2.50E-11 CAK=1.00E-12
.ENDS

**********************************************************************
* GENERIC: SV6AS7
* MODEL: NHSV6AS7
* NOTES: No heater model
**********************************************************************
.SUBCKT NHSV6AS7 A G K
XV1 A G K TRIODENH
+PARAMS: LIP= 1 LIF= 0.01 RAF= 0.0058 RAS= 0.7 CDO= 0
+ RAP= 0.035 ERP= 1.5
+ MU0= 2.05 MUR= 0.0017 EMC= 0.0005
+ GCO= 0 GCF= 0
+ CGA=1.10E-11 CGK=8.00E-12 CAK=3.00E-12
.ENDS

**********************************************************************
* GENERIC: 6BM8 / ECL82
* MODEL: NH6BM8
* NOTES: No heater or grid model
**********************************************************************
.SUBCKT NH6BM8 A G K
XV1 A G K TRIODENH
+PARAMS: LIP= 1.5 LIF= 10 RAF= 0.030667 RAS= 5 CDO=-0.5
+ RAP= 0.587 ERP= 1.5
+ MU0= 50 MUR= 0.035 EMC= 0.00000256
+ GCO= 0 GCF= 0
+ CGA=4.00E-12 CGK=2.70E-12 CAK=4.00E-12
.ENDS

**********************************************************************
* GENERIC: 6DJ8 / ECC88
* MODEL: NH6DJ8
* NOTES: No heater or grid current model
**********************************************************************
.SUBCKT NH6DJ8 A G K
XV1 A G K TRIODENH
+PARAMS: LIP= 1.5 LIF= 10 RAF= 0.09 RAS= 0.2 CDO= 0
+ RAP= 0 ERP= 1.35
+ MU0= 33 MUR= 0.02 EMC= 0.0000795
+ GCO=-0.2 GCF= 0
+ CGA=1.40E-12 CGK=3.30E-12 CAK=1.80E-12
.ENDS

**********************************************************************
* GENERIC: 6N1P
* MODEL: NH6N1P
* NOTES: No heater/grid model
**********************************************************************
.SUBCKT NH6N1P A G K
XV1 A G K TRIODENH
+PARAMS: LIP= 1.5 LIF= 10 RAF= 0.01 RAS= 1 CDO= 0
+ RAP= 0 ERP= 1.6
+ MU0= 37.5 MUR= 0.01 EMC= 0.000005
+ GCO= 0 GCF= 0
+ CGA=1.60E-12 CGK=3.20E-12 CAK=1.50E-12
.ENDS

**********************************************************************
* GENERIC: 6SN7GTB
* MODEL: 6SN7GTB
* NOTES: Has heater model (one half of heater)
**********************************************************************
.SUBCKT 6SN7GTB A G K H1 H2
XV1 A G K H1 H2 TRIODE
+PARAMS: RCO= 3.2 RHO= 21 HTV= 6.3 HWU= 10.5
+ LIP= 1 LIF= 0.0037 RAF= 0.02 RAS= 2 CDO= 0
+ RAP= 0.002 ERP= 1.4
+ MU0= 19.2642 MUR= 0.006167 EMC= 0.0000189
+ GCO= 0 GCF= 0.000213
+ CGA=3.90E-12 CGK=2.40E-12 CAK=7.00E-13
.ENDS

**********************************************************************
* GENERIC: 6SN7GTB
* MODEL: NH6SN7GTB
* NOTES: No heater model
**********************************************************************
.SUBCKT NH6SN7GTB A G K
XV1 A G K TRIODENH
+PARAMS: LIP= 1 LIF= 0.0037 RAF= 0.02 RAS= 2 CDO= 0
+ RAP= 0.002 ERP= 1.4
+ MU0= 19.2642 MUR= 0.006167 EMC= 0.0000189
+ GCO= 0 GCF= 0.000213
+ CGA=3.90E-12 CGK=2.40E-12 CAK=7.00E-13
.ENDS

**********************************************************************
* GENERIC: 12AT7 / ECC81
* MODEL: 12AT7
* NOTES: Heater model for one half of heater (6.3V)
**********************************************************************
.SUBCKT 12AT7 A G K H1 H2
XV1 A G K H1 H2 TRIODE
+PARAMS: RCO= 6.2 RHO= 42 HTV= 6.3 HWU= 10.5
+ LIP= 1 LIF= 0.0037 RAF= 0.09869 RAS= 1 CDO=-0.5
+ RAP= 0.1 ERP= 1.4
+ MU0= 45.093 MUR= 0.012937 EMC= 0.00000863
+ GCO=-0.5 GCF= 0.00012
+ CGA=1.60E-12 CGK=2.30E-12 CAK=4.00E-13
.ENDS

**********************************************************************
* GENERIC: 12AT7 / ECC81
* MODEL: NH12AT7
* NOTES: No heater model
**********************************************************************
.SUBCKT NH12AT7 A G K
XV1 A G K TRIODENH
+PARAMS: LIP= 1 LIF= 0.0037 RAF= 0.09869 RAS= 1 CDO=-0.5
+ RAP= 0.1 ERP= 1.4
+ MU0= 45.093 MUR= 0.012937 EMC= 0.00000863
+ GCO=-0.5 GCF= 0.00012
+ CGA=1.60E-12 CGK=2.30E-12 CAK=4.00E-13
.ENDS

**********************************************************************
* GENERIC: 12AU7 / ECC82
* MODEL: 12AU7
* NOTES: Heater model for one half of heater (6.3V)
**********************************************************************
.SUBCKT 12AU7 A G K H1 H2
XV1 A G K H1 H2 TRIODE
+PARAMS: RCO= 6.2 RHO= 42 HTV= 6.3 HWU= 10.5
+ LIP= 1 LIF= 0.0037 RAF= 0.024778659 RAS= 2.040491735 CDO= 0
+ RAP= 0.18 ERP= 1.35
+ MU0= 14.27427 MUR= 0.005857103 EMC= 0.0000236
+ GCO= 0 GCF= 0.00012
+ CGA=1.60E-12 CGK=1.80E-12 CAK=4.50E-13
.ENDS

**********************************************************************
* GENERIC: 12AU7 / ECC82
* MODEL: NH12AU7
* NOTES: No heater model
**********************************************************************
.SUBCKT NH12AU7 A G K
XV1 A G K TRIODENH
+PARAMS: LIP= 1 LIF= 0.0037 RAF= 0.000001 RAS= 2.065382774 CDO= 0
+ RAP= 0.18 ERP= 1.4
+ MU0= 17.08958652 MUR= 0.010938375 EMC= 0.0000183
+ GCO= 0 GCF= 0.00012
+ CGA=1.60E-12 CGK=1.80E-12 CAK=4.50E-13
.ENDS

**********************************************************************
* GENERIC: 12AX7 / ECC83
* MODEL: 12AX7
* NOTES: Heater model for one half of heater (6.3V)
**********************************************************************
.SUBCKT 12AX7 A G K H1 H2
XV1 A G K H1 H2 TRIODE
+PARAMS: RCO= 6.2 RHO= 42 HTV= 6.3 HWU= 10.5
+ LIP= 1.5 LIF= 0.000016 RAF= 0.076498 RAS= 1 CDO=-0.53056
+ RAP= 0.18 ERP= 1.5
+ MU0= 87.302 MUR=-0.013621 EMC= 0.00000111
+ GCO=-0.2 GCF= 0.00001
+ CGA=3.90E-12 CGK=2.40E-12 CAK=7.00E-13
.ENDS

**********************************************************************
* GENERIC: 12AX7 / ECC83
* MODEL: NH12AX7
* NOTES: No heater model
**********************************************************************
.SUBCKT NH12AX7 A G K
XV1 A G K TRIODENH
+PARAMS: LIP= 1.5 LIF= 0.000016 RAF= 0.076498 RAS= 1 CDO=-0.53056
+ RAP= 0.18 ERP= 1.5
+ MU0= 87.302 MUR=-0.013621 EMC= 0.00000111
+ GCO=-0.2 GCF= 0.00001
+ CGA=3.90E-12 CGK=2.40E-12 CAK=7.00E-13
.ENDS

**********************************************************************
* GENERIC: 76
* MODEL: NH76
* NOTES: No heater/grid model
**********************************************************************
.SUBCKT NH76 A G K
XV1 A G K TRIODENH
+PARAMS: LIP= 1 LIF= 10 RAF= 0.015 RAS= 1.8 CDO= 0
+ RAP= 0 ERP= 1.6
+ MU0= 12.8 MUR= 0.001 EMC= 0.000008
+ GCO= 0 GCF= 0
+ CGA=2.80E-12 CGK=3.50E-12 CAK=2.50E-12
.ENDS

**********************************************************************
* GENERIC: 300B
* MODEL: NH300B
* NOTES: No heater/grid model (virtual cathode)
**********************************************************************
.SUBCKT NH300B A G K
XV1 A G K TRIODENH
+PARAMS: LIP= 1 LIF= 10 RAF= 0.00311 RAS= 1.013608 CDO= 0
+ RAP= 0 ERP= 1.5
+ MU0= 3.7992 MUR= 0.000362 EMC= 0.000116
+ GCO= 0 GCF= 0
+ CGA=1.50E-11 CGK=9.00E-12 CAK=4.30E-12
.ENDS

**********************************************************************
* GENERIC: SV572-3
* MODEL: SV5723
* NOTES: No heater model (virtual cathode)
**********************************************************************
.SUBCKT SV5723 A G K
XV1 A G K TRIODENH
+PARAMS: LIP= 1 LIF= 0.0018 RAF= 0.0012 RAS= 0.5 CDO= 0
+ RAP= 0 ERP= 1.4
+ MU0= 3.79928 MUR= 0.0002 EMC= 0.0000425
+ GCO= 0 GCF= 0.0000349
+ CGA=4.00E-12 CGK=4.00E-12 CAK=1.00E-12
.ENDS

**********************************************************************
* GENERIC: SV572-10
* MODEL: SV57210
* NOTES: This model is not accurate for Vg >= +60V
**********************************************************************
.SUBCKT SV57210 A G K
XV1 A G K TRIODENH
+PARAMS: LIP= 1.4 LIF= 0.0008 RAF= 0.001 RAS= 1 CDO= 0
+ RAP=-0.00117 ERP= 1.38
+ MU0= 10 MUR= 0.0001 EMC= 0.0000272
+ GCO=-0.2 GCF= 0.0003
+ CGA=5.00E-12 CGK=6.40E-12 CAK=1.00E-12
.ENDS

**********************************************************************
* GENERIC: 5751
* MODEL: NH5751
* NOTES: No heater model
**********************************************************************
.SUBCKT NH5751 A G K
XV1 A G K TRIODENH
+PARAMS: LIP= 1.5 LIF= 0.000016 RAF= 0.075772 RAS= 1 CDO=-0.53056
+ RAP= 0.131285 ERP= 1.5
+ MU0= 62.94685 MUR=-0.0111 EMC= 0.00000142
+ GCO=-0.2 GCF= 0.00001
+ CGA=1.40E-12 CGK=1.40E-12 CAK=4.50E-13
.ENDS
Pozdrawiam
Grzegorz Makarewicz 'gsmok'
Awatar użytkownika
gsmok
3125...6249 postów
3125...6249 postów
Posty: 3807
Rejestracja: wt, 8 kwietnia 2003, 08:33
Lokalizacja: Warszawa
Kontakt:

Re: Symulator ułatwiający dobieranie punktu pracy lampy

Post autor: gsmok »

Symbole lamp w LTSpice:

Plik triode.asy

Version 4
SymbolType CELL
LINE Normal -48 0 -28 0
LINE Normal -20 0 -12 0
LINE Normal -4 0 4 0
LINE Normal 12 0 20 0
LINE Normal 28 0 36 0
LINE Normal 0 -48 0 -16
LINE Normal -20 -16 20 -16
LINE Normal -20 -12 20 -12
LINE Normal -20 -16 -20 -12
LINE Normal 20 -16 20 -12
LINE Normal -24 12 24 12
LINE Normal -32 48 -32 20
LINE Normal -24 12 -32 20
LINE Normal 24 12 32 20
LINE Normal -28 16 28 16
CIRCLE Normal -48 -48 48 48
WINDOW 0 8 -64 Left 2
WINDOW 3 -24 64 Left 2
SYMATTR Value Triode
SYMATTR Prefix X
SYMATTR Description This symbol is for use with a subcircuit macromodel that you supply.
PIN 0 -48 NONE 0
PINATTR PinName Plate
PINATTR SpiceOrder 1
PIN -48 0 NONE 0
PINATTR PinName Grid
PINATTR SpiceOrder 2
PIN -32 48 NONE 0
PINATTR PinName Cathode
PINATTR SpiceOrder 3


Plik tetrode.asy


Version 4
SymbolType CELL
LINE Normal -48 0 -48 16
LINE Normal 48 0 48 16
LINE Normal 0 -48 0 -16
LINE Normal -20 -16 20 -16
LINE Normal -20 -12 20 -12
LINE Normal -20 -16 -20 -12
LINE Normal 20 -16 20 -12
LINE Normal 48 0 28 0
LINE Normal 20 0 12 0
LINE Normal 4 0 -4 0
LINE Normal -12 0 -20 0
LINE Normal -28 0 -36 0
LINE Normal -48 16 -28 16
LINE Normal -20 16 -12 16
LINE Normal -4 16 4 16
LINE Normal 12 16 20 16
LINE Normal 28 16 36 16
LINE Normal -24 28 24 28
LINE Normal -32 64 -32 36
LINE Normal -24 28 -32 36
LINE Normal 24 28 32 36
LINE Normal -28 32 28 32
ARC Normal -48 -48 48 48 48 0 -48 0
ARC Normal -48 -32 48 64 -48 16 48 16
WINDOW 0 8 -64 Left 2
WINDOW 3 -24 80 Left 2
SYMATTR Value Tetrode
SYMATTR Prefix X
SYMATTR Description This symbol is for use with a subcircuit macromodel that you supply.
PIN 0 -48 NONE 0
PINATTR PinName Anode
PINATTR SpiceOrder 1
PIN 48 0 NONE 0
PINATTR PinName Screen
PINATTR SpiceOrder 2
PIN -48 16 NONE 0
PINATTR PinName Grid
PINATTR SpiceOrder 3
PIN -32 64 NONE 0
PINATTR PinName Cathode
PINATTR SpiceOrder 4
Pozdrawiam
Grzegorz Makarewicz 'gsmok'
BalROCK
50...74 posty
50...74 posty
Posty: 58
Rejestracja: sob, 5 lutego 2022, 17:55

Re: Symulator ułatwiający dobieranie punktu pracy lampy

Post autor: BalROCK »

Czy jest szansa na uzupełnienie tego zarąbistego narzędzia o lampy jak niżej?

ECC86
12AV7
12AZ7
ODPOWIEDZ